Uno de los servicios mas comunes que utiliza una conexión encriptado son los proveedores de correo usando IMAP.

Para este ejemplo vamos a conectarnos al servidor IMAP de Gmail y obtener el numero de mensajes nuevos y mensajes en total que existen en nuestra cuenta.

Para fines prácticos de este ejemplo necesitamos:

• Una cuenta de Gmail, con IMAP habilitado
• FlashBuilder
• Adobe AIR 2.0

Lo primero es crear una interfaz sencilla en donde se pueda insertar el nombre de usuario, la contraseña, campos de output y un boton para iniciar el proceso.

	<s:Label x="10" y="17" text="Gmail username:"/>
	<s:Label x="10" y="45" text="Gmail password:"/>
	<s:TextInput y="10" id="username_txt" change="_username = username_txt.text" right="10" left="120"/>
	<s:TextInput y="40" id="password_txt" change="_password = password_txt.text" displayAsPassword="true" right="10" left="120"/>
	<s:Button y="70" label="Tell me!!" click="start()" right="10"/>
	<s:Label x="10" y="100" width="280" id="result_txt"/>
	<s:TextArea id="out_txt" editable="false" right="10" bottom="10" top="130" left="10"/>

El resultado de esto se ve de esta forma:

Despues de tener nuestra interfaz vamos a declarar todas la variables y constantes que vamos a necesitar:

			/******************************************************************
			 *	Datos de la cuenta (Gmail IMAP)
			 * ***************************************************************/

			private static const INCOMING_SERVER:String = "imap.gmail.com";
			private static const PORT:int = 993;
			private var _username:String = "";
			private var _password:String = "";

			/******************************************************************
			 * Socket && Stuff
			 * ***************************************************************/ 

			private var _server:Socket;
			private var _buffer:ByteArray;
			private var _action:String;
			private var _totalMessages:String;
			private var _newMessages:String;

			/******************************************************************
			 * Respuestas del servidor (para filtar el contenido)
			 * http://tools.ietf.org/html/draft-gahrns-imap-namespace-00
			 * ****************************************************************/

			private static const CONNECT:String = "*";
			private static const LOGIN:String = "A002";
			private static const STATUS:String = "A006";
			private static const CRLF:String = "\r\n";
			private var _regSearch:RegExp = RegExp("\\"+_action+"\\r\\n");

Aqui hay un par de cosas que debo resaltar:

			private var _buffer:ByteArray;

En esta variable almacenaremos las respuestas que nos envié el servidor.

			private var _regSearch:RegExp = RegExp("\\"+_action+"\\r\\n");

Con esta expresion regular verificaremos si el mensaje que recibimos del servidor es util para nosotros.

			private static const CONNECT:String = "*";
			private static const LOGIN:String = "A002";
			private static const STATUS:String = "A006";

Estas constantes son los identificadores de los mensajes que se mandan desde y hacia el servidor para saber mas de estos identificadores recomiendo esta lectura http://tools.ietf.org/html/draft-gahrns-imap-namespace-00

Ahora nos queda inicializar nuestro socket y crear los eventos que usaremos para comunicarnos con el servidor

				_server = new SecureSocket();
				_server.addEventListener(Event.CONNECT, onConnect);
				_server.addEventListener(Event.CLOSE, onClose);
				_server.addEventListener(ProgressEvent.SOCKET_DATA, onData);
				_server.addEventListener(IOErrorEvent.IO_ERROR, onIOError);

El único cambio con respecto a trabajar con Sockets sin encriptar es el constructor de la clase en lugar de usar

				_server = new Socket();

Ahora debemos utilizar

				_server = new SecureSocket();

Así de simple; Bien, hemos seteado los listeners para CONNECT, SOCKET_DATA, CLOSE y IO_ERROR vamos a concentranos solamente en SOCKET_DATA que es el evento que se dispara al momento de recibir un mensaje del servidor.

			private function onData(e:ProgressEvent):void
			{
				out_txt.text += "Data " + e+"\n";
				var socket:Socket = e.target as Socket;
				var bufferString:String;
				socket.readBytes(_buffer, _buffer.length, socket.bytesAvailable);
				bufferString = _buffer.toString();
				out_txt.text += "SERVER: " + _buffer.toString()+"\n";
				if (  bufferString.search( _regSearch ) )
				{
					out_txt.text += "Es una respuesta valida parsea\n";
					parseResponse();
				}
				cursorManager.removeBusyCursor()
			}

En esta función recibimos el evento y tomamos el contenido del mensaje mediante el método readBytes y lo almacenamos en la variable _buffer

				socket.readBytes(_buffer, _buffer.length, socket.bytesAvailable);

Verificamos que el mensaje corresponda a nuestra petición, en este caso solo usamos 3 peticiones CONNECT, LOGIN, STATUS y si el mensaje es correcto parseamos el contenido.

El primer mensaje que recibimos del servidor es el de conexión

SERVER: * OK Gimap ready for requests from 189.216.40.184 14if7528374pzk.62

Una vez que estemos conectados mandamos nuestras credenciales para que el servidor nos autentique y cambiamos el mensaje a LOGIN indicando que estamos esperando el mensaje de respuesta de la solicitud de logueo.

				if ( _action == CONNECT )
				{
					out_txt.text += "Es es tag de conexion manda login\n";
					_server.writeUTFBytes(LOGIN + " LOGIN " + _username + " " + _password + CRLF);
					_action = LOGIN;
					_server.flush();
					return;
				}

Se envia el mensaje y de inmediato recibimos la respuesta del servidor, en caso de login correcto:

A002 OK tmeister@gmail.com authenticated (Success)

Si es incorrecto:

A002 NO [ALERT] Invalid credentials (Failure)

Con esto es muy fácil saber el resultado de la operación, usemos indexOf para saber si la palabra “OK” existe

				if ( _action == LOGIN )
				{
					out_txt.text += "Es la respuesta del login\n";
					if( bufferString.indexOf("OK") != -1 )
					{
						out_txt.text += "El login es correcto, estamos autenticados - Pedir correos sin leer\n";
						_action = STATUS;
						_server.writeUTFBytes(STATUS + " STATUS inbox (MESSAGES UNSEEN)" + CRLF);
						_server.flush();
					}else
					{
						out_txt.text += "Ooops!! Las credenciales no son validas.\n";
						Alert.show("Ooops!! Las credenciales no son validas.", "Error");
						_server.close();
					}
					return;
				}

Excelente estamos autenticados, Ahora que? solo nos falta pedir el estatus de la cuenta pidiendo los mensajes totales y los mensajes nuevos de la carpeta Inbox

						_server.writeUTFBytes(STATUS + " STATUS inbox (MESSAGES UNSEEN)" + CRLF);

El ultimo paso es recibir el mensaje del servidor con la información que pedimos y parsearla, al ser texto solo tenemos que usar indexOf y substring para acceder a lo que nos interesa

STATUS “inbox” (MESSAGES 61298 UNSEEN 5)

				if( _action == STATUS )
				{
					out_txt.text += "Es la respuesta del Status " + bufferString+"\n";
					var startSub:int = bufferString.indexOf("(");
					var endSub:int = bufferString.indexOf(")");
					var message:String = bufferString.substring(startSub+1, endSub);
					var slides:Array = message.split(" ");
					var count:int = 0;
					for each( var slide:String in slides )
					{
						switch( slide )
						{
							case "MESSAGES":
								_totalMessages = slides[count + 1];
								break;
							case "UNSEEN":
								_newMessages = slides[count + 1];
								break;
						}
						count++;
					}
					result_txt.text = _newMessages + " mensajes nuevos, de " + _totalMessages + " en total";
					out_txt.text += _totalMessages;
					out_txt.text += _newMessages;
					_action = null;
					_server.close();
				}
			}

Sin duda, lo mas complejo al momento de trabajar con Sockets es saber utilizar e implementar el protocolo de comunicación pero esa ya es otra historia.

Por ultimo les dejo el código completo

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
					   xmlns:s="library://ns.adobe.com/flex/spark"
					   xmlns:mx="library://ns.adobe.com/flex/halo"
					   creationComplete="init(event)"
					    width="300" height="250">
	<fx:Script>
		<![CDATA[
			import flash.events.Event;
			import flash.events.IOErrorEvent;
			import flash.events.MouseEvent;
			import flash.events.ProgressEvent;
			import flash.net.SecureSocket;
			import flash.net.Socket;
			import flash.utils.ByteArray;

			import mx.controls.Alert;
			import mx.events.FlexEvent;

			private static const INCOMING_SERVER:String = "imap.gmail.com";
			private static const PORT:int = 993;
			private var _username:String = "";
			private var _password:String = "";

			private var _server:Socket;
			private var _buffer:ByteArray;
			private var _action:String;
			private var _totalMessages:String;
			private var _newMessages:String;

			private static const CONNECT:String = "*";
			private static const LOGIN:String = "A002";
			private static const STATUS:String = "A006";
			private static const CRLF:String = "\r\n";
			private var _regSearch:RegExp = RegExp("\\"+_action+"\\r\\n");

			protected function init(event:FlexEvent):void
			{

				_server = new SecureSocket();
				_server.addEventListener(Event.CONNECT, onConnect);
				_server.addEventListener(Event.CLOSE, onClose);
				_server.addEventListener(ProgressEvent.SOCKET_DATA, onData);
				_server.addEventListener(IOErrorEvent.IO_ERROR, onIOError);

				_buffer = new ByteArray()
			}
			private function onConnect(e:Event):void
			{
				out_txt.text += "Conexion establecida " + e.toString()+"\n";
			}
			private function onClose(e:Event):void
			{
				out_txt.text += "Conexion cerrada " + e+"\n";
			}
			private function onData(e:ProgressEvent):void
			{
				out_txt.text += "Data " + e+"\n";
				var socket:Socket = e.target as Socket;
				var bufferString:String;
				socket.readBytes(_buffer, _buffer.length, socket.bytesAvailable);
				bufferString = _buffer.toString();
				out_txt.text += "SERVER: " + _buffer.toString()+"\n";
				if (  bufferString.search( _regSearch ) )
				{
					out_txt.text += "Es una respuesta valida parsea\n";
					parseResponse();
				}
				cursorManager.removeBusyCursor()
			}
			private function onIOError(e:IOErrorEvent):void
			{
				out_txt.text += "IOError " + e+"\n";
			}

			private function parseResponse():void
			{
				var bufferString:String = _buffer.toString();
				_buffer.clear();
				if ( _action == CONNECT )
				{
					out_txt.text += "Es es tag de conexion manda login\n";
					_server.writeUTFBytes(LOGIN + " LOGIN " + _username + " " + _password + CRLF);
					_action = LOGIN;
					_server.flush();
					return;
				}
				if ( _action == LOGIN )
				{
					out_txt.text += "Es la respuesta del login\n";
					if( bufferString.indexOf("OK") != -1 )
					{
						out_txt.text += "El login es correcto, estamos autenticados - Pedir correos sin leer\n";
						_action = STATUS;
						_server.writeUTFBytes(STATUS + " STATUS inbox (MESSAGES UNSEEN)" + CRLF);
						_server.flush();
					}else
					{
						out_txt.text += "Ooops!! Las credenciales no son validas.\n";
						Alert.show("Ooops!! Las credenciales no son validas.", "Error");
						_server.close();
					}
					return;
				}
				if( _action == STATUS )
				{
					out_txt.text += "Es la respuesta del Status " + bufferString+"\n";
					var startSub:int = bufferString.indexOf("(");
					var endSub:int = bufferString.indexOf(")");
					var message:String = bufferString.substring(startSub+1, endSub);
					var slides:Array = message.split(" ");
					var count:int = 0;
					for each( var slide:String in slides )
					{
						switch( slide )
						{
							case "MESSAGES":
								_totalMessages = slides[count + 1];
								break;
							case "UNSEEN":
								_newMessages = slides[count + 1];
								break;
						}
						count++;
					}
					result_txt.text = _newMessages + " mensajes nuevos, de " + _totalMessages + " en total";
					out_txt.text += _totalMessages;
					out_txt.text += _newMessages;
					_action = null;
					_server.close();
				}
			}

			private function start():void
			{
				out_txt.text = "iniciando Conexion\n";
				if( _server != null && _server.connected )
				{
					_server.close();
				}
				if( _username.length && _password.length )
				{
					_action = CONNECT;
					_server.connect(INCOMING_SERVER, PORT);
					cursorManager.setBusyCursor();
				}else
				{
					Alert.show("Escribe tus credenciales..", "Error");
				}
			}

		]]>
	</fx:Script>
	<s:Label x="10" y="17" text="Gmail username:"/>
	<s:Label x="10" y="45" text="Gmail password:"/>
	<s:TextInput y="10" id="username_txt" change="_username = username_txt.text" right="10" left="120"/>
	<s:TextInput y="40" id="password_txt" change="_password = password_txt.text" displayAsPassword="true" right="10" left="120"/>
	<s:Button y="70" label="Tell me!!" click="start()" right="10"/>
	<s:Label x="10" y="100" width="280" id="result_txt"/>
	<s:TextArea id="out_txt" editable="false" right="10" bottom="10" top="130" left="10"/>
</s:WindowedApplication>

Descarga

Espero les sea de ayuda y nos estamos leyendo.

Fecha: 18 de Noviembre 2009.
Hora: 9:00 am. a 2:00 pm.
Lugar: Universidad Iberoamericana.
Dirección: Prolongación Paseo de la Reforma 880, Lomas de Santa Fe, Mexico D.F.

Patrocinado por:

Adobe | Influxis

Twitter: @latinflashtour hashtag oficial #latinflashtour

Para ingresar al evento se debe presentar impreso el registro

Conferencistas Magistrales:

Todos ellos evangelistas de Adobe para la Plataforma Flash.

• Lee Brimelow (The Flash Blog & GotoAndLearn)
• Enrique Duvos (RIA Excellence & Made In Flex)
• Mike Chambers (Mike’s Blog)

Organizadores:

RIActive | RIAhispano | Flash MC

El día de hoy fue el lanzamiento oficial de este nuevo proyecto y los invito a que lo visiten y me dejen sus impresiones, comentarios, o sugerencias en el blog de desarrollo del proyecto donde pueden encontrar los detalles del lanzamiento .

En verdad agradeceré todo el feedback.

Enlace: Tweckr, The eyes of twitter
Blog: Tweckr, The eyes of twitter – Dev Blog.
Twitter: @Tweckr

Saludos!

Martes 14

Realidad Aumentada
Perú – Elder Vásquez (eldervaz)

Entrelazado vs progresivo en After Effects
España – Jorge Mochon

Contenido dinámico con InDesign
Colombia – Marlon Ceballos

Haciendo la Web más Dinámica con Premiere, Encore y After Effects
Rep.Dominicana – Luis Sosa

Miércoles 15

Experiencia del Usuario
México – Edgar Parada

Coldfusion 9
Ecuador – Michael Borbor

LiveCycle
Chile – Héctor Castro

Técnicas de Alto Rendimiento en Sitios Web
Argentina – Maximiliano R. Firtman

Jueves 16

AIR vs Flash Player API’s
España – Joan Garnet

Trabajo con Adobe BrowserLab
España – Andres Cayon

ActionScript 3.0
México – Alberto Gonzalez

Soluciones para real-time applications
Perú – Fernando Flórez (fernando)

Viernes 17

Mobile Video – Dandelion Player for Flash Lite
España – Raul Jimenez (elecash)

Juegos en Flash Lite
España – Marcos González

Flash Builder 4 – Data Centric Development
España – David Lopez

ADOBE
EEUU – John Koch – Community Manager
International Developer Relations Manager

Sábado 18

Flash Catalyst
España – Guillermo de la Iglesia (Zguillez)

El impacto de los Medios sociales
Bolivia – Daniel Sempértegui (DanielSemper)

Semántica en XHTML
Perú – Germán Martínez

Promete algo útil
Colombia – Freddie Vega (freddie)

Progressive Enhancement
Venezuela – César Frick (thefricky)

Equipos Web en el Mundo Real™
Perú – César Soplín (cesars)
Esta conferencia será transmitida por Adobe Connect, y para ello solo tienes que ingresar a la dirección web que será publicada el mismo día del evento.
Verifica la fecha y hora de cada charla en: http://www.adobenvivo.com/online/

La forma del dibujo cambia con cada refresh asi actualiza el navegador unas cuantas veces para que veas la diferencia.

[FLASH]http://klr20mg.com/wp-content/uploads/2009/07/tweet.swf, 400,400[/FLASH]

Aqui encuentran el Tweet original.

Y este el codigo completo

[as]

g=graphics;
mt=g.moveTo;
lt=g.lineTo;
ls=g.lineStyle;
m=Math;
r=m.random;
s=m.sin;
i=0;
o={};

function f(e)
{
if(o.k==null){a=3000;c=.1;x=y=200;o.k=r()*20}i-=.2;w=i*s(a*.1);e=i*m.cos(a*.1);g.beginFill(r()*000099,c);g.drawCircle(w,e,7);c+=.0002;a-=o.k
}
addEventListener(“enterFrame”,f);

[/as]

Saludos

Blueprint como ya dije es un plugin que se instala en Flex Builder o Flash Builder el cual permite un acceso rápido a referencias de código sobre un componente, clase o función haciendo la vida de los desarrolladores un poco mas sencilla (Si eso es posible :p ).

Con una combinacion de teclas ALT+b para Windows o  CTRL+b para Mac, se lanza una ventana de ayuda con las referencias de codigo del elemento seleccionado.

Blueprint se instala de una manera simple y sencilla y sin duda es de gran ayuda.

[Enlace] Blueprint

Sin duda son puntos sólidos a temer en cuenta, aquí un par de links que hablan sobre el tema.

• Writing well-behaved, efficient, AIR applications
• Performance Tips for Adobe AIR

Saludos!

Al día de hoy ya existen varias librerías para consumir el API de facebook en AS3, pero están incompletas, son muy bugies etc., Es por ello que facebook de asocio con Adobe para crear una librería de AS3 que este a la altura.

Esta librería es oficial y se une a la lista de librerías oficiales, PHP, iPhone y javascript.

Sin duda una de las más grandes ventajas de ser una librería oficial es el hecho de que cuenta con gran documentación e información.

El link de descarga de la librería es ActionScript 3.0 Client Library for Facebook
Documentación oficial de facebook
Documentación oficial de Adobe

Bien, con esto tenemos para jugar por un buen tiempo; Así que a programar se ha dicho

Saludos

Una solución simple es crear una clase singleton, en la cual, podemos almacenar no solo el stage principal, sino cualquier otro valor que necesitemos en varias clases. Algo así como _global de AS2, lo recuerdan?
Aquí la clase

[as]
package net.tmeister.utils
{
public dynamic class Global
{
private static var global : Global

public static function getInstance() : Global
{
if ( global == null )
{
global = new Global( arguments.callee );
}
return global;
}

public function Global( caller : Function = null )
{
if ( caller != Global.getInstance )
{
throw new Error (“Global is a singleton class, use getInstance() instead”);
}
if ( Global.global != null )
{
throw new Error( “Only one Global instance should be instantiated” );
}
}
}
}
[/as]

Y su modo de uso.

[as]
package
{
import flash.display.MovieClip;
import net.tmeister.utils.Global
public class Main extends MovieClip
{
private var global:Global;

public function Main()
{
global = Global.getInstance();
global.stage = stage
trace(‘global.stage’ + global.stage)
global.algunOtroValor = new MovieClip()
trace(‘global.algunOtroValor ‘ + global.algunOtroValor)
}
}
}
[/as]

Simple.

Main help portal
http://help.adobe.com/en_US/Flash/10.0_Welcome/

New features
http://help.adobe.com/en_US/…html

Programming ActionScript 3.0
http://help.adobe.com/…./

ActionScript 3.0 Language and Components Reference
http://help.adobe.com/en_US/AS3LCR/Flash_10.0/index.html

Extending Adobe Flash Professional CS4
http://help.adobe.com/…/index.html

Con esto, sin duda, ya tenemos para entretenernos un bien tiempo.

Hace un buen rato que no posteo, pero aquí estoy de vuelta con algo sencillo.
TiledBackground es una clase simple la cual toma una imagen externa (jpg, gif, png) y la repite tantas veces quepa en el navegador tal y como lo hiciéramos en CSS

Además de que tiene un par de parámetros, se puede sobreponer un gradiente radial para hacer un efecto sobre el fondo. Los colores y alphas del gradiente se pueden configurar.

TiledBackground
[as]
package net.tmeister.utils.background
{

import flash.display.BitmapData;
import flash.display.Loader;
import flash.display.Sprite;
import flash.display.Stage;
import flash.events.Event;
import flash.geom.Matrix;
import flash.net.URLRequest;
import flash.display.StageScaleMode;
import flash.display.StageAlign;
import flash.display.GradientType;

public class TiledBackground extends Sprite
{
private var _pattern:String;
private var _container:Sprite;
private var _image:Loader;
private var _stage:Stage;
private var _gradient:Boolean = true;
private var _gProperties:Object = {};

public function TiledBackground(stage:Stage)
{
_stage = stage
_stage.scaleMode = StageScaleMode.NO_SCALE;
_stage.align = StageAlign.TOP_LEFT;
_stage.addEventListener(Event.RESIZE, resize);
}
public function set pattern (urlPattern:String):void
{
_pattern = urlPattern;
loadPattern();
}
public function get pattern():String
{
return _pattern;
}
public function set radialGradient(value:Boolean):void
{
_gradient = value;
}
public function get radialGradient():Boolean
{
return _gradient;
}
public function set gradientProperties(properties:Object):void
{
_gProperties = properties;
}
public function get gradientProperties():Object
{
return _gProperties;
}
private function loadPattern():void
{
var patternLoader:Loader = new Loader();
var patternUrl:URLRequest = new URLRequest(_pattern);
patternLoader.load(patternUrl);
patternLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onPatternLoaded);
}
private function onPatternLoaded(e:Event):void
{
_image = e.target.loader;
createBackground();
createRadialGradient()
}
private function createBackground():void
{
if (_container != null)
{
removeChild(_container);
_container = null;
}
var bitmap:BitmapData = new BitmapData (_image.width, _image.height);
bitmap.draw(_image)
_container = new Sprite();
_container.graphics.beginBitmapFill(bitmap);
_container.graphics.drawRect(0,0, _stage.stageWidth , _stage.stageHeight);
_container.graphics.endFill();
addChild(_container);
}

private function createRadialGradient():void
{
if (! _gradient )
{
return;
}
var matrix:Matrix = new Matrix();
var gType:String = GradientType.RADIAL;
matrix.createGradientBox(_stage.stageWidth,_stage.stageHeight,0,0,0);
var gColors:Array = [(_gProperties.insideColor) ? _gProperties.insideColor : 0xffffff, (_gProperties.outsideColor) ? _gProperties.outsideColor : 0xffffff];
var gAlphas:Array = [(_gProperties.insideColorAlpha) ? _gProperties.insideColorAlpha : .15 ,(_gProperties.outsideColorAlpha) ? _gProperties.outsideColorAlpha : 0];
var gRatio:Array = [0,255];
var bound:Sprite = new Sprite();
bound.graphics.beginGradientFill(gType,gColors,gAlphas,gRatio,matrix);
bound.graphics.drawRect(0,0,_stage.stageWidth,_stage.stageHeight);
addChild(bound);
}
private function resize(e:Event):void
{
createBackground();
createRadialGradient()
}
}
}
[/as]
Uso:

[as]
package
{
import flash.display.Sprite;
import net.tmeister.utils.background.TiledBackground

public class sampleTiled extends Sprite
{
public function sampleTiled()
{
var background:TiledBackground = new TiledBackground(stage);
background.pattern = “bg1.gif”
background.gradientProperties = {insideColor:0xffffff, outsideColor:0xffffff, insideColorAlpha:.05, outsideColorAlpha:0}
addChild(background)
}
}
}
[/as]

Aquí el ejemplo y como siempre los archivos fuente están disponibles.

Saludos!!

getAllChilds

Regresa todos los hijos contenidos en el “target”

getChildsByType

Regresa solo los hijos que sean de un tipo específico, por ejemplo solo MovieClips, o solo Botones.

DisplayObjectUtils

[as]
package net.tmeister.utils
{
/**
* @author Enrique Chavez aka Tmeister
*/
import flash.display.DisplayObject;
public class DisplayObjectUtils
{
/**
*
* @param target
* @return Array
*/
public static function getAllChilds(target:*):Array
{
var listTmp:Array = []
for (var a = 0; a < target.numChildren; a++ )
{
listTmp.push (target.getChildAt(a) )
}
return listTmp
}
/**
*
* @param target
* @param type
* @return
*/
public static function getChildsByType(target:*, type:*):Array
{
var listTmp:Array = []
for (var a = 0; a < target.numChildren; a++ )
{
if (target.getChildAt(a) is type)
{
listTmp.push (target.getChildAt(a) )
}
}
return listTmp
}
}
}
[/as]

Su uso es el siguiente:

Primero creamos unos Movieclips y unos botones para tener algo que buscar.

[as]
import net.tmeister.utils.DisplayObjectUtils;
import fl.controls.Button

createMovieClips()
createButtons()
getChilds()

function createButtons()
{
for(var a:Number = 0; a<2; a++)
{
var tmp:Button = new Button();
tmp.x = Math.random()*400
tmp.y = Math.random()*400
tmp.label = “buton”+a
addChild(tmp)
}
}
function createMovieClips()
{
for(var a:Number = 0; a<5; a++)
{
var tmp:MovieClip = new MovieClip();
tmp.graphics.beginFill(0x2a2a2a, .5)
tmp.graphics.drawRect(Math.random()*500, Math.random()*300, Math.random()*100, Math.random()*100);
tmp.graphics.endFill();
tmp.name = “mc”+a;
addChild(tmp)
}
}
function getChilds()
{
trace(“All Childs: ” + DisplayObjectUtils.getAllChilds(this) )
trace(“=====================================================================================”)
trace(“Movieclips: ” + DisplayObjectUtils.getChildsByType(this, MovieClip))
trace(“=====================================================================================”)
trace(“Buttons: ” + DisplayObjectUtils.getChildsByType(this, Button))

}

[/as]

AS3 cuenta con su Math.round pero esta función lo único que hace es redondear el numero al entero más cercano. Pero qué pasa si quiero redondear un número en múltiplos de 5 por ejemplo.

Para ello escribí esta sencilla clase que lo permite.

[as]
package net.tmeister.utils
{
/**
*
* Advanced Round Class
* @version 0.1
* @author Enrique Chavez aka Tmeister
*
*/
public class MathUtils
{
/**
*
* Rounds a Number to the nearest multiple
* @param number Number to Round
* @param precision multiple to be rounded
* @return A number round
*
*/
public static function roundToNear(number:Number, precision:Number)
{
return Math.round( number / precision) * precision;
}
/**
*
* Rounds a Number up to the nearest multiple
* @param number Number to Round
* @param precision multiple to be rounded
* @return A number Up round
*
*/
public static function roundToUpNear(number:Number, precision:Number)
{
return Math.ceil( number / precision) * precision;
}
/**
*
* Rounds a Number down to the nearest multiple
* @param number number Number to Round
* @param precision multiple to be rounded
* @return A number down round
*
*/
public static function roundToDownNear(number:Number, precision:Number)
{
return Math.floor( number / precision) * precision;
}
}
}
[/as]

Modo de uso es tan simple como esto.

[as]
import net.tmeister.utils.MathUtils;

const number:Number = 38
const precision:Number = 5

trace(MathUtils.roundToNear(number, precision)) // 40
trace(MathUtils.roundToUpNear(number, precision)) // 40
trace(MathUtils.roundToDownNear(number, precision)) // 35
[/as]

Enjoy

Voy a tratar hacer una definición de los ValueObjects sin ser muy técnico. de ahora en adelante al usar VO me estaré refiriendo a los ValueObjects. Los puntos mas importantes de los VO son:

1. Los VO son contenedores de información representada por una clase individual.
2. Los VO son serializables, es decir, pueden ser enviados entre un servidor y un cliente mantenido sus propiedades.

Imaginemos que vamos a hacer un listado de mensajes para un guestbook, pero no sabemos quien, que o como nos van a proveer la información, lo único sabemos son los atributos que contendrá cada mensaje, estos son:

• idUnique
• author
• url
• content

Los mensajes siempre contendrán estas propiedades vengan de donde vengan.

Según el punto 1 esta información es representada por una clase individual entonces como nuestro cliente será hecho el FLEX creamos nuestro clase en AS3 la cual representara nuestros VO en el cliente.

[as]

package com.klr20mg.pureMVC.guestbook.model.vo
{
[RemoteClass(alias="MessagesVO")]
[Bindable]
public class MessagesVO
{
public var idUnique:String;
public var author:String;
public var url:String;
public var content:String;
public function MessagesVO(author:String=null, url:String=null, content:String=null)
{
this.idUnique = “”
this.author = author;
this.url = url;
this.content = content;
}
}
}

[/as]

Hay 2 formas comunes de “poblar” los VO mediante el constructor, como en este ejemplo o mediante getters y setters, yo prefiero la primera.

Ahora vamos crear un VO a partir de la clase anterior

[as]

package com.klr20mg.pureMVC.guestbook
{
import com.klr20mg.pureMVC.guestbook.model.vo.MessagesVO
public class someClass
{
public function someClass()
{
var miVO:MessagesVO = new MessagesVO(“Tmeister”, “http://tmeister.net”, “Este es un mensaje de prueba”);
trace(miVO)
}
}
}

[/as]

Con esto hemos creado un VO de acuerdo a la primera clase.

Los VO son “compatibles” entre el cliente y el servidor según el punto numero 2, y al usar AMFPHP, WebOrb entre otros podemos enviar arrays de VO’s entre el server y el cliente sin ningún problema, pero entonces debemos de crear nuestros VO’s en el servidor en este caso usando PHP para poder “mapear” esta información.

<?php
class MessagesVO
{
    public $idUnique;
    public $author;
    public $url;
    public $content; 

    public function MessagesVO()
    {
    }
    public function mapObject($data)
    {
        $this->idUnique = $data["idUnique"];
        $this->author = $data["author"];
        $this->url = $data["url"];
        $this->content = $data["content"];
    }
}
?>

Como pueden ver es el mismo concepto encapsular la información en una clase.

Con esto, repito, no importa si la información viene de archivos de texto, de un webservice, de una base de datos, siempre podremos almacenar, consultar y modificar la información mediante nuestros VO’s.

Espero que con esto quede claro que son y para que usan los ValueObjects

Saludos

¿Que significa esto?

Significa que podemos crear base de datos locales desde nuestra aplicación de AIR sin la necesidad de que el usuario final instale nada más que el Runtime de AIR.

Con esto podemos crear eliminar modificar bases de datos, tablas, registro etc.

Para propósitos de este tutorial vamos a crear un simple cliente que cree una base de datos si no existe, que cree la tabla con la cual trabajaremos y donde consultaremos, agregaremos y eliminaremos entradas.

Cabe mencionar que para efectos prácticos no posteare todo el código en cada ejemplo. Al final del tutorial estará la clase final así como los archivos fuente para su estudio

Creación de Base de Datos

Al ser una base de datos local, evidentemente dicho archivo se tiene que crear en la maquina del usuario, para saber si la base de datos existe o no, debemos verificar si el archivo existe, para ello hacemos uso de la Clase File

[as]
package com.tmeister.samples.sql
{
import flash.filesystem.File;

public class sqlSample extends MovieClip
{
private var db:File;

public function sqlSample()
{
db = File.applicationStorageDirectory.resolvePath(“myFirst.db”);
(!db.exists) ? createDatabase() : dbExist();
}
private function createDatabase()
{
trace(“Creamos la BD”)
}
private function dbExist()
{
trace(“La Base de datos ya existe”)
}
}
}
[/as]

Con esto sabremos si la base de datos existe o no, si dicha base de datos no existe debemos crearla, pero antes de poder crearla debemos crear una instancia de la clase SQLConnection para poder conectarnos con el engine y después de esto entonces si crear la BD.

[as]
//Importamos las clases para trabajar con SQLite
import flash.data.SQLConnection;
import flash.events.SQLErrorEvent;
import flash.events.SQLEvent;

//Creamos una nueva conexion y seteamos sus respectivos handlers
conn = new SQLConnection();
conn.addEventListener(SQLEvent.OPEN, dbConnOpen);
conn.addEventListener(SQLErrorEvent.ERROR, dbConnError);

//”Abrimos” la base de datos, si no existe se crea
conn.openAsync(db);

// Handlers de los eventos
private function dbConnOpen(e:SQLEvent)
{
trace(“Se conecto a la base de datos “)
trace(“Ya podemos hacer uso de la base de datos.”)
}
private function dbConnError(e:SQLErrorEvent)
{
trace(“Error al conectarse a la base de datos”);
trace(e)
}
[/as]

En esta parte de código asignamos 2 listeners a conn que es nuestra conexión con el engine, Los listeners son:

• SQLEvent.OPEN : El cual se ejecuta cuando la base de datos esta lista para ser usada.
• SQLErrorEvent.ERROR : El cual se ejecuta si un error ocurrió al momento de intentar acceder a la base de datos.

La línea “mágica” es

[as]
conn.openAsync(db);
[/as]

Con esta instrucción abrimos la base de datos pasando como referencia el archivo respectivo, si el archivo no existe se crea automáticamente. Hay dos formas de trabajar con SQLite, de forma Síncrona o Asíncrona, en este ejemplo trabajamos con la segunda opción, en una entrada posterior tratare de explicar las diferencias entre cada una de ellas.

Con esto ya tenemos una base de datos creada ahora lo siguiente es crear un tabla

Creación de Tablas

Una vez que ya tenemos nuestra base de datos ahora necesitamos una tabla en donde insertar datos.

Las interacciones hacia la base de datos es exactamente igual que en otros lenguajes de programación (dígase PHP), se crea la conexión a la base de datos se escribe el SQL y se ejecuta la instrucción.

Lo único que cambia en AS3 es que debemos crear una instancia de la clase SQLStatement en la cual seteamos que conexión a DB usar, asignar la cadena de consulta o ejecución (SQL) y asignar los valores.

Todo esto se resume a lo siguiente.

[as]
import flash.events.SQLErrorEvent;
import flash.events.SQLEvent;

private const TABLE_NAME:String = “people”

//Creamos una instancia de la clase
var dbManager:SQLStatement = new SQLStatement();

//Asignamos la conexion a la base de datos
dbManager.sqlConnection = conn

//Asignamos listeners a los eventos
dbManager.addEventListener(SQLErrorEvent.ERROR, sqlError);
dbManager.addEventListener(SQLEvent.RESULT, tableResult);

//Sentencia a ejecutar
var sql:String = “CREATE TABLE ” + TABLE_NAME + ” (“;
sql += “id INTEGER PRIMARY KEY AUTOINCREMENT,”
sql += “name TEXT,”;
sql += “age NUMERIC”;
sql += “)”;

//La sentencia SQL debe ser asignada a la propiedad text del SQLStatement
dbManager.text = sql;

//Por ultimo ejecutamos la sentencia
dbManager.execute();

//Handlers
private function tableResult(e:SQLEvent)
{
trace(“La tabla se creo correctamente”);
}
private function sqlError(e:SQLErrorEvent)
{
trace(“Error: “+ e.error.message);
trace(“Detalles: “+ e.error.details);
}
[/as]

Inserts

Como mencione antes todas las interacciones con la base de datos se deben de hacer mediante una instancia de la clase SQLStatement. Lo único que cambia de acuerdo con el ejemplo anterior (Creación de tablas) es la sentencia SQL y la asignación de los valores de los campos.

Ejemplo de Insert

[as]
import flash.events.SQLErrorEvent;
import flash.events.SQLEvent;

//Creamos una instancia de la clase
var insertManager:SQLStatement = new SQLStatement();

//Asignamos la conexion a la base de datos
insertManager.sqlConnection = conn;

//Asignamos listeners a los eventos
insertManager.addEventListener(SQLEvent.RESULT, insertResult);
insertManager.addEventListener(SQLErrorEvent.ERROR, sqlError);

//Sentencia a ejecutar
var sql:String = “INSERT INTO ” + TABLE_NAME + ” (name, age) VALUES (:name, :age)”;

//Asignacion de valor a los parametros de la sentencia
insertManager.parameters[":name"] = “Tmeister”;
insertManager.parameters[":age"] = “29″;

//La sentencia SQL debe ser asignada a la propiedad text del SQLStatement
insertManager.text = sql;

//Por ultimo ejecutamos la sentencia
insertManager.execute();

//Handlers
private function tableResult(e:SQLEvent)
{
trace(“La tabla se creo correctamente”);
}
private function sqlError(e:SQLErrorEvent)
{
trace(“Error: “+ e.error.message);
trace(“Detalles: “+ e.error.details);
}
[/as]

Aqui vemos cosas nuevas en la sentencia.

Primero

[as]
var sql:String = “INSERT INTO ” + TABLE_NAME + ” (name, age) VALUES (:name, :age)”;
[/as]

Si pueden ver los valores de los campos están precedidos de dos puntos : esto significa que son parámetros de la sentencia.

La clase SQLStatement tiene una propiedad llamada parameters que es un Array en donde se tiene que asignar el valor de cada parámetro escrito en nuestra sentencia, en este ejemplo tenemos 2 parámetros :name y :age entonces necesitamos asignarle valores esto se hace con estas líneas

[as]
insertManager.parameters[":name"] = “Tmeister”;
insertManager.parameters[":age"] = “29″;
[/as]

En realidad es algo simple. no?

Obteniendo datos de la base de datos

Para obtener datos de la base de datos es exactamente lo mismo que hicimos para crear la tabla, solamente cambia la sentencia SQL

[as]
import flash.events.SQLErrorEvent;
import flash.events.SQLEvent;
import flash.data.SQLStatement;

private const TABLE_NAME:String = “people”

//Creamos una instancia de la clase
var query:SQLStatement = new SQLStatement();

//Asignamos la conexion a la base de datos
query.sqlConnection = conn

//Asignamos listeners a los eventos
query.addEventListener(SQLErrorEvent.ERROR, sqlError);
query.addEventListener(SQLEvent.RESULT, sqlResult);

//Sentencia a ejecutar
var sql:String = “SELECT * FROM ” + TABLE_NAME + ” order by id”;

//La sentencia SQL debe ser asignada a la propiedad text del SQLStatement
query.text = sql;

//Por ultimo ejecutamos la sentencia
query.execute();

private function sqlError(e:SQLErrorEvent)
{
trace(“Error: “+ e.error.message);
trace(“Detalles: “+ e.error.details);
}
private function sqlResult(e:SQLEvent)
{
var result:SQLResult = e.target.getResult();
for each ( var row:Object in result.data)
{
trace(row)
trace(row.id)
trace(row.name)
//etc
}
}
[/as]

Para obtener el resultado de la consulta de debemos ejecutar la función getResult de la instancia SQLStatement.

[as]
var result:SQLResult = e.target.getResult();
[/as]

Por último solo queda recorrer los resultados, que son devueltos como objetos

[as]
for each ( var row:Object in result.data)
{
trace(row)
trace(row.id)
trace(row.name)
//etc
}
[/as]

Con esto ya podemos comenzar a trabajar con SQLite para manejar información en la maquina local del usuario final.